This script was also modified because of an issue locating the Windows RE tools partition for deployment of the WinRE image.

The change is around line 113 in the MDT 2013 Update 1 version.

bUnMapDrive = false
set oDiskPart = GetBootDriveEx ( false, "", true )
if oDiskPart is Nothing then
    bUnMapDrive = true
    oLogging.CreateEntry "The drive letter for the boot partition was not found.", LogTypeInfo
    set oDiskPart = GetBootDriveEx ( true, "", true )
    TestAndFail not oDiskPart is nothing, 10501, "Verify a boot drive object was returned."
    oLogging.CreateEntry "Found object: " & oDiskPart.oWMIDiskPart.Path_, LogTypeInfo
End if

'****** MODIFIED CODE BELOW
oLogging.CreateEntry "*********************************************************", LogTypeInfo
oLogging.CreateEntry "Manual intervention to locate Windows RE tools volume", LogTypeInfo
Dim scVols, scVol, scWMI
oLogging.CreateEntry "Getting access to WMI", LogTypeInfo
Set scWMI = GetObject("winmgmts://./root/cimv2")
oLogging.CreateEntry "Querying for Logical Disks with Volume Label of Windows RE tools", LogTypeInfo
Set scVols = scWMI.ExecQuery("Select * from Win32_LogicalDisk where VolumeName='Windows RE tools'")
Dim scParts, scPart oLogging.CreateEntry "Parsing results of Logical Disk query", LogTypeInfo
For Each scVol in scVols
    oLogging.CreateEntry "Found volume at drive " & scVol.Name & ".", LogTypeInfo
    oLogging.CreateEntry "Querying for partitions associated with Logical Disk", LogTypeInfo
    Set scParts = scWMI.ExecQuery("ASSOCIATORS OF {" & scVol.Path_ & "} WHERE AssocClass = Win32_LogicalDiskToPartition")
    For Each scPart in scParts
        oLogging.CreateEntry "Found partition at " & scPart.Path_, LogTypeInfo
        oLogging.CreateEntry "Creating new ZTIDiskPartition Object", LogTypeInfo
        Set oDiskPart = new ZTIDiskPartition
        oLogging.CreateEntry "Assigning found partition to ZTIDiskPartition.DiskPart", LogTypeInfo
        Set oDiskPart.DiskPart = scPart
        oLogging.CreateEntry "Assignment completed", LogTypeInfo
    Next
Next
'****** END MODIFIED CODE

TestAndFail oDiskPart.Drive <> "", 10502, "Verify a drive was returned: " & oDiskPart.Drive